55a401e607
This CL moves BitrateAdjuster into common_video folder as it was suggested on [0] such that it can be properly linked with Chrome projects. [0] https://codereview.chromium.org/1818903004/ BUG=500605 Review URL: https://codereview.webrtc.org/1914893005 Cr-Commit-Position: refs/heads/master@{#12515}
75 lines
1.9 KiB
Plaintext
75 lines
1.9 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../build/webrtc.gni")
|
|
|
|
config("common_video_config") {
|
|
include_dirs = [
|
|
"include",
|
|
"libyuv/include",
|
|
]
|
|
}
|
|
|
|
source_set("common_video") {
|
|
sources = [
|
|
"bitrate_adjuster.cc",
|
|
"i420_buffer_pool.cc",
|
|
"include/bitrate_adjuster.h",
|
|
"include/frame_callback.h",
|
|
"include/i420_buffer_pool.h",
|
|
"include/incoming_video_stream.h",
|
|
"include/video_frame_buffer.h",
|
|
"incoming_video_stream.cc",
|
|
"libyuv/include/scaler.h",
|
|
"libyuv/include/webrtc_libyuv.h",
|
|
"libyuv/scaler.cc",
|
|
"libyuv/webrtc_libyuv.cc",
|
|
"video_frame.cc",
|
|
"video_frame_buffer.cc",
|
|
"video_render_frames.cc",
|
|
"video_render_frames.h",
|
|
]
|
|
|
|
include_dirs = [ "../modules/interface" ]
|
|
|
|
configs += [ "..:common_config" ]
|
|
public_configs = [
|
|
"..:common_inherited_config",
|
|
":common_video_config",
|
|
]
|
|
|
|
if (is_clang) {
|
|
# Suppress warnings from Chrome's Clang plugins.
|
|
# See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
|
|
configs -= [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
deps = [
|
|
"..:webrtc_common",
|
|
"../system_wrappers",
|
|
]
|
|
|
|
if (rtc_build_libyuv) {
|
|
deps += [ "$rtc_libyuv_dir" ]
|
|
public_deps = [
|
|
"$rtc_libyuv_dir",
|
|
]
|
|
} else {
|
|
# Need to add a directory normally exported by libyuv.
|
|
include_dirs += [ "$rtc_libyuv_dir/include" ]
|
|
}
|
|
|
|
if (is_ios || is_mac) {
|
|
sources += [
|
|
"corevideo_frame_buffer.cc",
|
|
"include/corevideo_frame_buffer.h",
|
|
]
|
|
libs = [ "CoreVideo.framework" ]
|
|
}
|
|
}
|