e0629c045e
Make all rtc_source_test target that contains tests that are included in a test executable only be visible to the rtc_test target. Doing this exposed a couple of errors and dependency problems that were resolved. Having this could have prevented duplicated execution of tests like the case that was recently fixed by deadbeef@ in https://codereview.webrtc.org/2820263004 New targets: * //webrtc/modules/rtp_rtcp:fec_test_helper * //webrtc/modules/rtp_rtcp:mock_rtp_rtcp * //webrtc/modules/remote_bitrate_estimator:mock_remote_bitrate_observer The mock files and targets should probably be moved into webrtc/test in the future, but that's out of the scope of this CL. BUG=webrtc:5716 NOTRY=True Review-Url: https://codereview.webrtc.org/2828793003 Cr-Commit-Position: refs/heads/master@{#17863}
63 lines
1.8 KiB
Plaintext
63 lines
1.8 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../webrtc.gni")
|
|
|
|
rtc_static_library("utility") {
|
|
sources = [
|
|
"include/audio_frame_operations.h",
|
|
"include/helpers_android.h",
|
|
"include/jvm_android.h",
|
|
"include/process_thread.h",
|
|
"source/helpers_android.cc",
|
|
"source/jvm_android.cc",
|
|
"source/process_thread_impl.cc",
|
|
"source/process_thread_impl.h",
|
|
]
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
if (is_ios) {
|
|
libs = [ "AVFoundation.framework" ]
|
|
}
|
|
|
|
deps = [
|
|
"../..:webrtc_common",
|
|
"../../audio/utility:audio_frame_operations",
|
|
"../../base:rtc_task_queue",
|
|
"../../common_audio",
|
|
"../../system_wrappers",
|
|
"../media_file",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("utility_unittests") {
|
|
testonly = true
|
|
|
|
# Skip restricting visibility on mobile platforms since the tests on those
|
|
# gets additional generated targets which would require many lines here to
|
|
# cover (which would be confusing to read and hard to maintain).
|
|
if (!is_android && !is_ios) {
|
|
visibility = [ "//webrtc/modules:modules_unittests" ]
|
|
}
|
|
sources = [
|
|
"source/process_thread_impl_unittest.cc",
|
|
]
|
|
deps = [
|
|
":utility",
|
|
"../../base:rtc_task_queue",
|
|
"../../test:test_support",
|
|
"//testing/gmock",
|
|
]
|
|
}
|
|
}
|