99a2c5dcb6
Allows mixing up to 4 input streams. Useful for profiling and manual tests. Allows testing different combinations of input/output rates and number of channels. Reads and writes WAV files. Can also configure whether to use the Limiter component of the AudioMixer. Bug: webrtc:8925 Change-Id: Iaf4fee5284980f6ed01f4bb721e49bb1af8dd392 Reviewed-on: https://webrtc-review.googlesource.com/56842 Commit-Queue: Alex Loiko <aleloi@webrtc.org> Reviewed-by: Alessio Bazzica <alessiob@webrtc.org> Cr-Commit-Position: refs/heads/master@{#22209}
119 lines
2.9 KiB
Plaintext
119 lines
2.9 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../webrtc.gni")
|
|
|
|
group("audio_mixer") {
|
|
deps = [
|
|
":audio_frame_manipulator",
|
|
":audio_mixer_impl",
|
|
]
|
|
}
|
|
|
|
rtc_static_library("audio_mixer_impl") {
|
|
sources = [
|
|
"audio_mixer_impl.cc",
|
|
"audio_mixer_impl.h",
|
|
"default_output_rate_calculator.cc",
|
|
"default_output_rate_calculator.h",
|
|
"frame_combiner.cc",
|
|
"frame_combiner.h",
|
|
"output_rate_calculator.h",
|
|
]
|
|
|
|
public = [
|
|
"audio_mixer_impl.h",
|
|
"default_output_rate_calculator.h", # For creating a mixer with limiter disabled.
|
|
"frame_combiner.h",
|
|
]
|
|
|
|
configs += [ "../audio_processing:apm_debug_dump" ]
|
|
|
|
deps = [
|
|
":audio_frame_manipulator",
|
|
"..:module_api",
|
|
"../..:webrtc_common",
|
|
"../../:typedefs",
|
|
"../../api:array_view",
|
|
"../../api/audio:audio_mixer_api",
|
|
"../../audio/utility:audio_frame_operations",
|
|
"../../common_audio",
|
|
"../../rtc_base:checks",
|
|
"../../rtc_base:rtc_base_approved",
|
|
"../../system_wrappers",
|
|
"../../system_wrappers:field_trial_api",
|
|
"../audio_processing",
|
|
"../audio_processing:apm_logging",
|
|
"../audio_processing:audio_frame_view",
|
|
"../audio_processing/agc2:agc2",
|
|
]
|
|
}
|
|
|
|
rtc_static_library("audio_frame_manipulator") {
|
|
visibility = [
|
|
":*",
|
|
"../../modules:*",
|
|
]
|
|
|
|
sources = [
|
|
"audio_frame_manipulator.cc",
|
|
"audio_frame_manipulator.h",
|
|
]
|
|
|
|
deps = [
|
|
"..:module_api",
|
|
"../../audio/utility:audio_frame_operations",
|
|
"../../rtc_base:checks",
|
|
"../../rtc_base:rtc_base_approved",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("audio_mixer_unittests") {
|
|
testonly = true
|
|
|
|
sources = [
|
|
"audio_frame_manipulator_unittest.cc",
|
|
"audio_mixer_impl_unittest.cc",
|
|
"frame_combiner_unittest.cc",
|
|
"gain_change_calculator.cc",
|
|
"gain_change_calculator.h",
|
|
"sine_wave_generator.cc",
|
|
"sine_wave_generator.h",
|
|
]
|
|
|
|
deps = [
|
|
":audio_frame_manipulator",
|
|
":audio_mixer_impl",
|
|
"..:module_api",
|
|
"../../api:array_view",
|
|
"../../api/audio:audio_mixer_api",
|
|
"../../audio/utility:audio_frame_operations",
|
|
"../../rtc_base:checks",
|
|
"../../rtc_base:rtc_base_approved",
|
|
"../../rtc_base:rtc_task_queue_for_test",
|
|
"../../test:test_support",
|
|
]
|
|
}
|
|
|
|
rtc_executable("audio_mixer_test") {
|
|
testonly = true
|
|
sources = [
|
|
"audio_mixer_test.cc",
|
|
]
|
|
|
|
deps = [
|
|
":audio_mixer_impl",
|
|
"../../api/audio:audio_mixer_api",
|
|
"../../common_audio",
|
|
"../../rtc_base:rtc_base_approved",
|
|
"../../system_wrappers:system_wrappers_default",
|
|
]
|
|
}
|
|
}
|