16ccfdf457
Patchset 1 is patchset #5 id:80001 of https://codereview.webrtc.org/2717983003/ Patchset 2 fix call_perf_test dep on fake_audio_device. This reverts commit 985371bda999c6db51286586c5850d2ff58f3511. Original cl description: Move fake_audio_device to its own target. The purpose is to make it usefull for test targets that does not need or can use test_common. For some reason this also triggered override issues in rtp module tests that are fixed in the same cl. BUG=none TBR=kjellander@webrtc.org NOTRY=True Review-Url: https://codereview.webrtc.org/2718363002 Cr-Commit-Position: refs/heads/master@{#16922}
133 lines
3.6 KiB
Plaintext
133 lines
3.6 KiB
Plaintext
# Copyright (c) 2015 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../webrtc.gni")
|
|
|
|
rtc_source_set("call_interfaces") {
|
|
sources = [
|
|
"audio_receive_stream.h",
|
|
"audio_send_stream.cc",
|
|
"audio_send_stream.h",
|
|
"audio_state.h",
|
|
"call.h",
|
|
"flexfec_receive_stream.h",
|
|
"syncable.cc",
|
|
"syncable.h",
|
|
]
|
|
deps = [
|
|
"..:webrtc_common",
|
|
"../api:audio_mixer_api",
|
|
"../api:transport_api",
|
|
"../api/audio_codecs:audio_codecs_api",
|
|
"../base:rtc_base",
|
|
"../base:rtc_base_approved",
|
|
"../modules/audio_coding:audio_encoder_interface",
|
|
]
|
|
}
|
|
|
|
rtc_static_library("call") {
|
|
sources = [
|
|
"bitrate_allocator.cc",
|
|
"call.cc",
|
|
"flexfec_receive_stream_impl.cc",
|
|
"flexfec_receive_stream_impl.h",
|
|
]
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
public_deps = [
|
|
":call_interfaces",
|
|
"../api:call_api",
|
|
]
|
|
|
|
deps = [
|
|
":call_interfaces",
|
|
"..:webrtc_common",
|
|
"../api:transport_api",
|
|
"../audio",
|
|
"../base:rtc_task_queue",
|
|
"../logging:rtc_event_log_api",
|
|
"../logging:rtc_event_log_impl",
|
|
"../modules/bitrate_controller",
|
|
"../modules/congestion_controller",
|
|
"../modules/pacing",
|
|
"../modules/rtp_rtcp",
|
|
"../modules/utility",
|
|
"../system_wrappers",
|
|
"../video",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("call_tests") {
|
|
testonly = true
|
|
sources = [
|
|
"bitrate_allocator_unittest.cc",
|
|
"bitrate_estimator_tests.cc",
|
|
"call_unittest.cc",
|
|
"flexfec_receive_stream_unittest.cc",
|
|
]
|
|
deps = [
|
|
":call",
|
|
"../base:rtc_base_approved",
|
|
"../logging:rtc_event_log_api",
|
|
"../modules/audio_device:mock_audio_device",
|
|
"../modules/audio_mixer",
|
|
"../modules/bitrate_controller",
|
|
"../modules/pacing",
|
|
"../modules/rtp_rtcp",
|
|
"../system_wrappers",
|
|
"../test:direct_transport",
|
|
"../test:test_common",
|
|
"../test:test_support",
|
|
"../test:video_test_common",
|
|
"//testing/gmock",
|
|
"//testing/gtest",
|
|
]
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
|
|
rtc_source_set("call_perf_tests") {
|
|
testonly = true
|
|
sources = [
|
|
"call_perf_tests.cc",
|
|
"rampup_tests.cc",
|
|
"rampup_tests.h",
|
|
]
|
|
deps = [
|
|
":call_interfaces",
|
|
"..:webrtc_common",
|
|
"../base:rtc_base_approved",
|
|
"../logging:rtc_event_log_api",
|
|
"../modules/audio_coding",
|
|
"../modules/audio_mixer:audio_mixer_impl",
|
|
"../modules/rtp_rtcp",
|
|
"../system_wrappers",
|
|
"../system_wrappers:metrics_default",
|
|
"../test:direct_transport",
|
|
"../test:fake_audio_device",
|
|
"../test:test_support",
|
|
"../test:video_test_common",
|
|
"../video",
|
|
"../voice_engine",
|
|
"//testing/gtest",
|
|
"//webrtc/test:test_common",
|
|
]
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
}
|