6e0c145538
Change log:191d55580e..f7f609d28cFull diff:191d55580e..f7f609d28cRoll chromium third_party 3a8f2a9e1e..70ec6906a5 Change log:3a8f2a9e1e..70ec6906a5Changed dependencies: * src/base:6cb1af46fc..deb9ad0180* src/build:c9bb242447..27de0fa05e* src/buildtools:0b71401b97..a9e946f166* src/ios:41a7632e36..f1ab343a06* src/testing:519bd6bd88..81ba8e08f4* src/third_party/catapult: https://chromium.googlesource.com/catapult.git/+log/a75468d15a..195c52dc70 * src/third_party/depot_tools:e7273d2501..d1de725e0b* src/third_party/winsdk_samples:601401003b..f7874f6eb6* src/tools:f524a53b81..9d42b89d62DEPS diff:191d55580e..f7f609d28c/DEPS No update to Clang. TBR=buildbot@webrtc.org, BUG=None CQ_INCLUDE_TRYBOTS=master.internal.tryserver.corp.webrtc:linux_internal Change-Id: Ib5977d73d64db73b31e8add9410c4fabced7f9b3 Reviewed-on: https://webrtc-review.googlesource.com/76504 Reviewed-by: WebRTC Buildbot <buildbot@webrtc.org> Commit-Queue: WebRTC Buildbot <buildbot@webrtc.org> Cr-Commit-Position: refs/heads/master@{#23219}
177 lines
5.6 KiB
Plaintext
177 lines
5.6 KiB
Plaintext
# Copyright 2014 The Chromium Authors. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
import("//build_overrides/build.gni")
|
|
|
|
config("gtest_config") {
|
|
visibility = [ ":*" ] # gmock also shares this config.
|
|
|
|
defines = [
|
|
# Chromium always links googletest statically, so no API qualifier is
|
|
# necessary. The definition in gtest-port.h at the time of this writing
|
|
# causes crashes in content_browsertests.
|
|
"GTEST_API_=",
|
|
|
|
# In order to allow regex matches in gtest to be shared between Windows
|
|
# and other systems, we tell gtest to always use its internal engine.
|
|
"GTEST_HAS_POSIX_RE=0",
|
|
|
|
# Enables C++11 features.
|
|
"GTEST_LANG_CXX11=1",
|
|
|
|
# Prevents gtest from including both <tr1/tuple> and <tuple>.
|
|
"GTEST_HAS_TR1_TUPLE=0",
|
|
]
|
|
|
|
# Gtest headers need to be able to find themselves.
|
|
include_dirs = [
|
|
"custom",
|
|
"src/googletest/include",
|
|
]
|
|
|
|
if (is_win) {
|
|
cflags = [ "/wd4800" ] # Unused variable warning.
|
|
}
|
|
}
|
|
|
|
config("gmock_config") {
|
|
# Gmock headers need to be able to find themselves.
|
|
include_dirs = [
|
|
"custom",
|
|
"src/googlemock/include",
|
|
]
|
|
|
|
if (is_clang) {
|
|
# TODO(tikuta): remove this when the issue is fixed.
|
|
# https://github.com/google/googletest/issues/533
|
|
cflags = [ "-Wno-inconsistent-missing-override" ]
|
|
}
|
|
}
|
|
|
|
# Do NOT depend on this directly. Use //testing/gtest instead.
|
|
# See README.chromium for details.
|
|
source_set("gtest") {
|
|
testonly = true
|
|
sources = [
|
|
"custom/gtest/internal/custom/gtest.h",
|
|
"custom/gtest/internal/custom/stack_trace_getter.cc",
|
|
"custom/gtest/internal/custom/stack_trace_getter.h",
|
|
"src/googletest/include/gtest/gtest-death-test.h",
|
|
"src/googletest/include/gtest/gtest-message.h",
|
|
"src/googletest/include/gtest/gtest-param-test.h",
|
|
"src/googletest/include/gtest/gtest-printers.h",
|
|
"src/googletest/include/gtest/gtest-spi.h",
|
|
"src/googletest/include/gtest/gtest-test-part.h",
|
|
"src/googletest/include/gtest/gtest-typed-test.h",
|
|
"src/googletest/include/gtest/gtest.h",
|
|
"src/googletest/include/gtest/gtest_pred_impl.h",
|
|
"src/googletest/include/gtest/internal/gtest-death-test-internal.h",
|
|
"src/googletest/include/gtest/internal/gtest-filepath.h",
|
|
"src/googletest/include/gtest/internal/gtest-internal.h",
|
|
"src/googletest/include/gtest/internal/gtest-linked_ptr.h",
|
|
"src/googletest/include/gtest/internal/gtest-param-util-generated.h",
|
|
"src/googletest/include/gtest/internal/gtest-param-util.h",
|
|
"src/googletest/include/gtest/internal/gtest-port.h",
|
|
"src/googletest/include/gtest/internal/gtest-string.h",
|
|
"src/googletest/include/gtest/internal/gtest-tuple.h",
|
|
"src/googletest/include/gtest/internal/gtest-type-util.h",
|
|
|
|
#"src/googletest/src/gtest-all.cc", # Not needed by our build.
|
|
"src/googletest/src/gtest-death-test.cc",
|
|
"src/googletest/src/gtest-filepath.cc",
|
|
"src/googletest/src/gtest-internal-inl.h",
|
|
"src/googletest/src/gtest-port.cc",
|
|
"src/googletest/src/gtest-printers.cc",
|
|
"src/googletest/src/gtest-test-part.cc",
|
|
"src/googletest/src/gtest-typed-test.cc",
|
|
"src/googletest/src/gtest.cc",
|
|
]
|
|
|
|
# Some files include "src/gtest-internal-inl.h".
|
|
include_dirs = [ "src/googletest" ]
|
|
|
|
all_dependent_configs = [ ":gtest_config" ]
|
|
|
|
configs -= [ "//build/config/compiler:chromium_code" ]
|
|
configs += [ "//build/config/compiler:no_chromium_code" ]
|
|
|
|
defines = []
|
|
if (is_nacl || !build_with_chromium) {
|
|
defines += [ "GTEST_DISABLE_PRINT_STACK_TRACE" ]
|
|
sources -= [
|
|
"custom/gtest/internal/custom/stack_trace_getter.cc",
|
|
"custom/gtest/internal/custom/stack_trace_getter.h",
|
|
]
|
|
} else {
|
|
deps = [
|
|
"//base",
|
|
]
|
|
if (is_fuchsia) {
|
|
deps += [
|
|
"//third_party/fuchsia-sdk:fdio",
|
|
"//third_party/fuchsia-sdk:launchpad",
|
|
]
|
|
}
|
|
}
|
|
}
|
|
|
|
# Do NOT depend on this directly. Use //testing/gtest:gtest_main instead.
|
|
# See README.chromium for details.
|
|
source_set("gtest_main") {
|
|
testonly = true
|
|
sources = [
|
|
"src/googletest/src/gtest_main.cc",
|
|
]
|
|
deps = [
|
|
":gtest",
|
|
]
|
|
}
|
|
|
|
# Do NOT depend on this directly. Use //testing/gmock:gmock_main instead.
|
|
# See README.chromium for details.
|
|
source_set("gmock") {
|
|
testonly = true
|
|
sources = [
|
|
"src/googlemock/include/gmock/gmock-actions.h",
|
|
"src/googlemock/include/gmock/gmock-cardinalities.h",
|
|
"src/googlemock/include/gmock/gmock-generated-actions.h",
|
|
"src/googlemock/include/gmock/gmock-generated-function-mockers.h",
|
|
"src/googlemock/include/gmock/gmock-generated-matchers.h",
|
|
"src/googlemock/include/gmock/gmock-generated-nice-strict.h",
|
|
"src/googlemock/include/gmock/gmock-matchers.h",
|
|
"src/googlemock/include/gmock/gmock-spec-builders.h",
|
|
"src/googlemock/include/gmock/gmock.h",
|
|
"src/googlemock/include/gmock/internal/gmock-generated-internal-utils.h",
|
|
"src/googlemock/include/gmock/internal/gmock-internal-utils.h",
|
|
"src/googlemock/include/gmock/internal/gmock-port.h",
|
|
|
|
# gmock helpers.
|
|
"custom/gmock/internal/custom/gmock-port.h",
|
|
|
|
#"src/googlemock/src/gmock-all.cc", # Not needed by our build.
|
|
"src/googlemock/src/gmock-cardinalities.cc",
|
|
"src/googlemock/src/gmock-internal-utils.cc",
|
|
"src/googlemock/src/gmock-matchers.cc",
|
|
"src/googlemock/src/gmock-spec-builders.cc",
|
|
"src/googlemock/src/gmock.cc",
|
|
]
|
|
|
|
public_configs = [
|
|
":gmock_config",
|
|
":gtest_config",
|
|
]
|
|
}
|
|
|
|
# Do NOT depend on this directly. Use //testing/gmock:gmock_main instead.
|
|
# See README.chromium for details.
|
|
static_library("gmock_main") {
|
|
testonly = true
|
|
sources = [
|
|
"src/googlemock/src/gmock_main.cc",
|
|
]
|
|
deps = [
|
|
":gmock",
|
|
]
|
|
}
|