5f5819f8ed
Change log:105c043148..cb8b61b491Full diff:105c043148..cb8b61b491Roll chromium third_party 6cd8e71424..b0f19bfaad Change log:6cd8e71424..b0f19bfaadChanged dependencies: * src/base:95c3466bc7..4d325e07ed* src/build:7ccebdabd9..c3e2883ba8* src/ios:a5c76c8f1d..720bfc790a* src/testing:7c8625bcae..12897eb458* src/third_party/catapult: https://chromium.googlesource.com/catapult.git/+log/44fc6f687b..53842b6cbc * src/third_party/depot_tools:a28b14f122..04925ac3f7* src/third_party/icu:f61e46dbee..172d33141c* src/tools:7d0c51bb6e..674f7d10b4DEPS diff:105c043148..cb8b61b491/DEPS No update to Clang. TBR=buildbot@webrtc.org, BUG=None CQ_INCLUDE_TRYBOTS=master.internal.tryserver.corp.webrtc:linux_internal NO_AUTOIMPORT_DEPS_CHECK=true Change-Id: I364bd1247061abf1532c89587d22f819fcb2e73e Reviewed-on: https://webrtc-review.googlesource.com/84880 Commit-Queue: WebRTC Buildbot <buildbot@webrtc.org> Reviewed-by: WebRTC Buildbot <buildbot@webrtc.org> Cr-Commit-Position: refs/heads/master@{#23717}
98 lines
2.5 KiB
Plaintext
98 lines
2.5 KiB
Plaintext
# Copyright (c) 2018 The Chromium Authors. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
# Flags specified here must not impact ABI. Code compiled with and without these
|
|
# opts will be linked together, and in some cases headers compiled with and
|
|
# without these options will be part of the same program.
|
|
|
|
import("//build/toolchain/toolchain.gni")
|
|
|
|
group("default") {
|
|
deps = [
|
|
"absl/types:any",
|
|
"absl/types:bad_any_cast",
|
|
"absl/types:span",
|
|
"absl/types:optional",
|
|
"absl/types:bad_optional_access",
|
|
]
|
|
}
|
|
|
|
config("absl_include_config") {
|
|
# Using -isystem (with clang and GCC) and -imsvc (with clang-cl) instead of
|
|
# include_dirs (-I), so we don't need to suppress warnings coming from
|
|
# Abseil. Doing so would mask warnings in our own code.
|
|
if (is_win) {
|
|
if (is_clang) {
|
|
# clang-cl:
|
|
cflags = [
|
|
"-imsvc",
|
|
rebase_path(".", root_build_dir),
|
|
]
|
|
} else {
|
|
# MSVC doesn't have -isystem, in that case we fallback to include_dirs and
|
|
# we use the warning suppression flags defined in :absl_default_cflags_cc.
|
|
include_dirs = [ "." ]
|
|
}
|
|
} else {
|
|
# GCC or clang:
|
|
cflags = [
|
|
"-isystem",
|
|
rebase_path(".", root_build_dir),
|
|
]
|
|
}
|
|
}
|
|
|
|
config("absl_define_config") {
|
|
defines = [ "ABSL_ALLOCATOR_NOTHROW=1" ]
|
|
}
|
|
|
|
config("absl_default_cflags_cc") {
|
|
cflags_cc = []
|
|
if (is_clang) {
|
|
cflags_cc += [
|
|
# TODO(crbug.com/588506): Explicitly enable conversion warnings.
|
|
"-Wbool-conversion",
|
|
"-Wconstant-conversion",
|
|
"-Wenum-conversion",
|
|
"-Wint-conversion",
|
|
"-Wliteral-conversion",
|
|
"-Wnon-literal-null-conversion",
|
|
"-Wnull-conversion",
|
|
"-Wobjc-literal-conversion",
|
|
"-Wno-sign-conversion",
|
|
"-Wstring-conversion",
|
|
]
|
|
if (!is_nacl && !use_xcode_clang) {
|
|
cflags_cc += [ "-Wbitfield-enum-conversion" ]
|
|
}
|
|
}
|
|
if (is_win) {
|
|
cflags_cc += [
|
|
"/wd4005", # macro-redefinition
|
|
"/wd4068", # unknown pragma
|
|
"/wd4702", # unreachable code
|
|
]
|
|
}
|
|
}
|
|
|
|
config("absl_test_cflags_cc") {
|
|
cflags_cc = []
|
|
if (is_clang || !is_win) {
|
|
cflags_cc += [
|
|
"-Wno-conversion-null",
|
|
"-Wno-missing-declarations",
|
|
"-Wno-sign-compare",
|
|
"-Wno-unused-function",
|
|
"-Wno-unused-parameter",
|
|
"-Wno-unused-private-field",
|
|
]
|
|
}
|
|
if (is_win) {
|
|
cflags_cc += [
|
|
"/wd4018", # signed/unsigned mismatch
|
|
"/wd4101", # unreferenced local variable
|
|
]
|
|
}
|
|
}
|