66e7338617
This is a reland of 2b242d8fba59ccf67e4c5bcf5a1ea80917a23e1c Original change's description: > Merge cpu_features build targets into //system_wrappers. > > Before this CL, functions declared in cpu_features_wrapper.h where > not defined in the same build target, causing brittle builds that > might fail at link time if the binary was not depending on > //system_wrappers (the target with the definitions), violating [1]. > > This CL moves everything into //system_wrappers and also moves > cpu_features_wrapper.h definitions from C to C++ (in order to be able > to add the definitions to a C++ build target like //system_wrappers). > > [1] - https://webrtc.googlesource.com/src/+/refs/heads/master/style-guide.md#h-cc-pairs > > Bug: None > Change-Id: I5a0009cddb17206b19f2a71eeba722faacc4bcae > Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/183380 > Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> > Reviewed-by: Karl Wiberg <kwiberg@webrtc.org> > Cr-Commit-Position: refs/heads/master@{#32039} TBR=kwiberg@webrtc.org Bug: None Change-Id: I1695b9a34d3ec20c50c1202a745f64fac58edef0 Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/183444 Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> Cr-Commit-Position: refs/heads/master@{#32042}
143 lines
3.5 KiB
Plaintext
143 lines
3.5 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
if (is_android) {
|
|
import("//build/config/android/config.gni")
|
|
import("//build/config/android/rules.gni")
|
|
}
|
|
import("../webrtc.gni")
|
|
|
|
rtc_library("system_wrappers") {
|
|
visibility = [ "*" ]
|
|
sources = [
|
|
"include/clock.h",
|
|
"include/cpu_features_wrapper.h",
|
|
"include/cpu_info.h",
|
|
"include/ntp_time.h",
|
|
"include/rtp_to_ntp_estimator.h",
|
|
"include/sleep.h",
|
|
"source/clock.cc",
|
|
"source/cpu_features.cc",
|
|
"source/cpu_info.cc",
|
|
"source/rtp_to_ntp_estimator.cc",
|
|
"source/sleep.cc",
|
|
]
|
|
|
|
defines = []
|
|
libs = []
|
|
deps = [
|
|
"../api:array_view",
|
|
"../api/units:timestamp",
|
|
"../modules:module_api_public",
|
|
"../rtc_base:checks",
|
|
"../rtc_base/synchronization:mutex",
|
|
"../rtc_base/synchronization:rw_lock_wrapper",
|
|
"../rtc_base/system:arch",
|
|
"../rtc_base/system:rtc_export",
|
|
]
|
|
absl_deps = [ "//third_party/abseil-cpp/absl/types:optional" ]
|
|
|
|
if (is_android) {
|
|
if (build_with_mozilla) {
|
|
include_dirs = [
|
|
"/config/external/nspr",
|
|
"/nsprpub/lib/ds",
|
|
"/nsprpub/pr/include",
|
|
]
|
|
} else {
|
|
sources += [ "source/cpu_features_android.cc" ]
|
|
deps += [ "//third_party/android_sdk:cpu_features" ]
|
|
}
|
|
|
|
libs += [ "log" ]
|
|
}
|
|
|
|
if (is_linux) {
|
|
if (!build_with_chromium) {
|
|
sources += [ "source/cpu_features_linux.cc" ]
|
|
}
|
|
|
|
libs += [ "rt" ]
|
|
}
|
|
|
|
if (is_win) {
|
|
libs += [ "winmm.lib" ]
|
|
|
|
# Windows needs ../rtc_base due to include of
|
|
# webrtc/rtc_base/win32.h in source/clock.cc.
|
|
deps += [ "../rtc_base" ]
|
|
}
|
|
|
|
deps += [
|
|
"../rtc_base:rtc_base_approved",
|
|
"../rtc_base:rtc_numerics",
|
|
]
|
|
}
|
|
|
|
rtc_library("field_trial") {
|
|
visibility = [ "*" ]
|
|
public = [ "include/field_trial.h" ]
|
|
sources = [ "source/field_trial.cc" ]
|
|
if (rtc_exclude_field_trial_default) {
|
|
defines = [ "WEBRTC_EXCLUDE_FIELD_TRIAL_DEFAULT" ]
|
|
}
|
|
deps = [
|
|
"../rtc_base:checks",
|
|
"../rtc_base:logging",
|
|
"../rtc_base:stringutils",
|
|
]
|
|
absl_deps = [ "//third_party/abseil-cpp/absl/strings" ]
|
|
}
|
|
|
|
rtc_library("metrics") {
|
|
visibility = [ "*" ]
|
|
public = [ "include/metrics.h" ]
|
|
sources = [ "source/metrics.cc" ]
|
|
if (rtc_exclude_metrics_default) {
|
|
defines = [ "WEBRTC_EXCLUDE_METRICS_DEFAULT" ]
|
|
}
|
|
deps = [
|
|
"../rtc_base:checks",
|
|
"../rtc_base:rtc_base_approved",
|
|
"../rtc_base/synchronization:mutex",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_test("system_wrappers_unittests") {
|
|
testonly = true
|
|
sources = [
|
|
"source/clock_unittest.cc",
|
|
"source/field_trial_unittest.cc",
|
|
"source/metrics_default_unittest.cc",
|
|
"source/metrics_unittest.cc",
|
|
"source/ntp_time_unittest.cc",
|
|
"source/rtp_to_ntp_estimator_unittest.cc",
|
|
]
|
|
|
|
deps = [
|
|
":field_trial",
|
|
":metrics",
|
|
":system_wrappers",
|
|
"../rtc_base:checks",
|
|
"../rtc_base:rtc_base_approved",
|
|
"../test:rtc_expect_death",
|
|
"../test:test_main",
|
|
"../test:test_support",
|
|
"//testing/gtest",
|
|
"//third_party/abseil-cpp/absl/strings",
|
|
]
|
|
|
|
if (is_android) {
|
|
deps += [ "//testing/android/native_test:native_test_support" ]
|
|
|
|
shard_timeout = 900
|
|
}
|
|
}
|
|
}
|