1140f97e48
Reason for revert: Fixing the Gn error and try to reland. Original issue's description: > Revert of Creating webrtc/modules:module_api (patchset #5 id:80001 of https://codereview.webrtc.org/2838873002/ ) > > Reason for revert: > Causes build problem: https://build.chromium.org/p/client.webrtc/builders/iOS64%20Sim%20Debug%20%28iOS%209.0%29/builds/1630/steps/generate%20build%20files%20%28mb%29/logs/stdio > > Original issue's description: > > Creating webrtc/modules:module_api > > > > This target keeps track of .h the files under webrtc/modules/include/ > > that are not part of any target. > > If a .h file is not part of a target the 'gn check' utility is not > > able to spot if a target is missing a dependency because even if > > it parses '#include' directives it is not able to find a target that > > contains these headers. > > > > BUG=webrtc:7513 > > NOTRY=True > > > > Review-Url: https://codereview.webrtc.org/2838873002 > > Cr-Commit-Position: refs/heads/master@{#17880} > > Committed:5a1a092ed0> > TBR=kjellander@webrtc.org > # Skipping CQ checks because original CL landed less than 1 days ago. > NOPRESUBMIT=true > NOTREECHECKS=true > NOTRY=true > BUG=webrtc:7513 > > Review-Url: https://codereview.webrtc.org/2839963005 > Cr-Commit-Position: refs/heads/master@{#17881} > Committed:bb08c3e296TBR=kjellander@webrtc.org # Skipping CQ checks because original CL landed less than 1 days ago. NOPRESUBMIT=true NOTREECHECKS=true NOTRY=true TBR=kjellander@webrtc.org BUG=webrtc:7513 Review-Url: https://codereview.webrtc.org/2843913002 Cr-Commit-Position: refs/heads/master@{#17884}
127 lines
3.4 KiB
Plaintext
127 lines
3.4 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("//build/config/arm.gni")
|
|
import("../../webrtc.gni")
|
|
|
|
build_video_processing_sse2 = current_cpu == "x86" || current_cpu == "x64"
|
|
|
|
rtc_static_library("video_processing") {
|
|
sources = [
|
|
"util/denoiser_filter.cc",
|
|
"util/denoiser_filter_c.cc",
|
|
"util/denoiser_filter_c.h",
|
|
"util/noise_estimation.cc",
|
|
"util/noise_estimation.h",
|
|
"util/skin_detection.cc",
|
|
"util/skin_detection.h",
|
|
"video_denoiser.cc",
|
|
"video_denoiser.h",
|
|
]
|
|
|
|
deps = [
|
|
":denoiser_filter",
|
|
"..:module_api",
|
|
"../../base:rtc_base_approved",
|
|
"../../common_audio",
|
|
"../../common_video",
|
|
"../../modules/utility",
|
|
"../../system_wrappers",
|
|
]
|
|
if (build_video_processing_sse2) {
|
|
deps += [ ":video_processing_sse2" ]
|
|
}
|
|
if (rtc_build_with_neon) {
|
|
deps += [ ":video_processing_neon" ]
|
|
}
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
|
|
rtc_source_set("denoiser_filter") {
|
|
# Target that only exists to avoid cyclic depdency errors for the SSE2 and
|
|
# Neon implementations below.
|
|
sources = [
|
|
"util/denoiser_filter.h",
|
|
]
|
|
deps = [
|
|
"..:module_api",
|
|
]
|
|
}
|
|
|
|
if (build_video_processing_sse2) {
|
|
rtc_static_library("video_processing_sse2") {
|
|
sources = [
|
|
"util/denoiser_filter_sse2.cc",
|
|
"util/denoiser_filter_sse2.h",
|
|
]
|
|
|
|
deps = [
|
|
":denoiser_filter",
|
|
"../../base:rtc_base_approved",
|
|
"../../system_wrappers",
|
|
]
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
if (is_posix) {
|
|
cflags = [ "-msse2" ]
|
|
}
|
|
}
|
|
}
|
|
|
|
if (rtc_build_with_neon) {
|
|
rtc_static_library("video_processing_neon") {
|
|
sources = [
|
|
"util/denoiser_filter_neon.cc",
|
|
"util/denoiser_filter_neon.h",
|
|
]
|
|
|
|
deps = [
|
|
":denoiser_filter",
|
|
]
|
|
|
|
if (current_cpu != "arm64") {
|
|
suppressed_configs += [ "//build/config/compiler:compiler_arm_fpu" ]
|
|
cflags = [ "-mfpu=neon" ]
|
|
}
|
|
}
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("video_processing_unittests") {
|
|
testonly = true
|
|
|
|
# Skip restricting visibility on mobile platforms since the tests on those
|
|
# gets additional generated targets which would require many lines here to
|
|
# cover (which would be confusing to read and hard to maintain).
|
|
if (!is_android && !is_ios) {
|
|
visibility = [ "//webrtc/modules:modules_unittests" ]
|
|
}
|
|
sources = [
|
|
"test/denoiser_test.cc",
|
|
]
|
|
deps = [
|
|
":video_processing",
|
|
"../../common_video:common_video",
|
|
"../../test:test_support",
|
|
"../../test:video_test_common",
|
|
]
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
}
|