317a1f09ed
WebRTC is now using C++14 so there is no need to use the Abseil version of std::make_unique. This CL has been created with the following steps: git grep -l absl::make_unique | sort | uniq > /tmp/make_unique.txt git grep -l absl::WrapUnique | sort | uniq > /tmp/wrap_unique.txt git grep -l "#include <memory>" | sort | uniq > /tmp/memory.txt diff --new-line-format="" --unchanged-line-format="" \ /tmp/make_unique.txt /tmp/wrap_unique.txt | sort | \ uniq > /tmp/only_make_unique.txt diff --new-line-format="" --unchanged-line-format="" \ /tmp/only_make_unique.txt /tmp/memory.txt | \ xargs grep -l "absl/memory" > /tmp/add-memory.txt git grep -l "\babsl::make_unique\b" | \ xargs sed -i "s/\babsl::make_unique\b/std::make_unique/g" git checkout PRESUBMIT.py abseil-in-webrtc.md cat /tmp/add-memory.txt | \ xargs sed -i \ 's/#include "absl\/memory\/memory.h"/#include <memory>/g' git cl format # Manual fix order of the new inserted #include <memory> cat /tmp/only_make_unique | xargs grep -l "#include <memory>" | \ xargs sed -i '/#include "absl\/memory\/memory.h"/d' git ls-files | grep BUILD.gn | \ xargs sed -i '/\/\/third_party\/abseil-cpp\/absl\/memory/d' python tools_webrtc/gn_check_autofix.py \ -m tryserver.webrtc -b linux_rel # Repead the gn_check_autofix step for other platforms git ls-files | grep BUILD.gn | \ xargs sed -i 's/absl\/memory:memory/absl\/memory/g' git cl format Bug: webrtc:10945 Change-Id: I3fe28ea80f4dd3ba3cf28effd151d5e1f19aff89 Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/153221 Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Alessio Bazzica <alessiob@webrtc.org> Reviewed-by: Karl Wiberg <kwiberg@webrtc.org> Cr-Commit-Position: refs/heads/master@{#29209}
163 lines
4.3 KiB
Plaintext
163 lines
4.3 KiB
Plaintext
# Copyright (c) 2018 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../webrtc.gni")
|
|
|
|
rtc_source_set("emulated_network") {
|
|
visibility = [
|
|
"../../api:create_network_emulation_manager",
|
|
":*",
|
|
]
|
|
if (rtc_include_tests) {
|
|
visibility += [
|
|
"../scenario:*",
|
|
"../peer_scenario:*",
|
|
]
|
|
}
|
|
testonly = true
|
|
sources = [
|
|
"cross_traffic.cc",
|
|
"cross_traffic.h",
|
|
"emulated_network_manager.cc",
|
|
"emulated_network_manager.h",
|
|
"fake_network_socket.cc",
|
|
"fake_network_socket.h",
|
|
"fake_network_socket_server.cc",
|
|
"fake_network_socket_server.h",
|
|
"network_emulation.cc",
|
|
"network_emulation.h",
|
|
"network_emulation_manager.cc",
|
|
"network_emulation_manager.h",
|
|
"simulated_network_node.cc",
|
|
"simulated_network_node.h",
|
|
"traffic_route.cc",
|
|
"traffic_route.h",
|
|
]
|
|
deps = [
|
|
"../../api:network_emulation_manager_api",
|
|
"../../api:simulated_network_api",
|
|
"../../api/units:data_rate",
|
|
"../../api/units:data_size",
|
|
"../../api/units:time_delta",
|
|
"../../api/units:timestamp",
|
|
"../../call:simulated_network",
|
|
"../../rtc_base",
|
|
"../../rtc_base:rtc_base_tests_utils",
|
|
"../../rtc_base:rtc_task_queue",
|
|
"../../rtc_base:safe_minmax",
|
|
"../../rtc_base:task_queue_for_test",
|
|
"../../rtc_base/synchronization:sequence_checker",
|
|
"../../rtc_base/task_utils:repeating_task",
|
|
"../../rtc_base/third_party/sigslot",
|
|
"../../system_wrappers",
|
|
"../scenario:column_printer",
|
|
"../time_controller",
|
|
"//third_party/abseil-cpp/absl/memory",
|
|
"//third_party/abseil-cpp/absl/types:optional",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("network_emulation_unittest") {
|
|
testonly = true
|
|
sources = [
|
|
"network_emulation_unittest.cc",
|
|
]
|
|
deps = [
|
|
":emulated_network",
|
|
"../:test_support",
|
|
"../../api:simulated_network_api",
|
|
"../../api/units:time_delta",
|
|
"../../call:simulated_network",
|
|
"../../rtc_base:gunit_helpers",
|
|
"../../rtc_base:logging",
|
|
"../../rtc_base:rtc_event",
|
|
"../../system_wrappers:system_wrappers",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("network_emulation_pc_unittest") {
|
|
testonly = true
|
|
sources = [
|
|
"network_emulation_pc_unittest.cc",
|
|
]
|
|
deps = [
|
|
":emulated_network",
|
|
"../:test_support",
|
|
"../../api:callfactory_api",
|
|
"../../api:libjingle_peerconnection_api",
|
|
"../../api:scoped_refptr",
|
|
"../../api:simulated_network_api",
|
|
"../../api/rtc_event_log:rtc_event_log_factory",
|
|
"../../api/task_queue:default_task_queue_factory",
|
|
"../../call:simulated_network",
|
|
"../../media:rtc_audio_video",
|
|
"../../media:rtc_media_engine_defaults",
|
|
"../../modules/audio_device:audio_device_impl",
|
|
"../../p2p:rtc_p2p",
|
|
"../../pc:pc_test_utils",
|
|
"../../pc:peerconnection_wrapper",
|
|
"../../rtc_base",
|
|
"../../rtc_base:gunit_helpers",
|
|
"../../rtc_base:logging",
|
|
"../../rtc_base:rtc_event",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("cross_traffic_unittest") {
|
|
testonly = true
|
|
sources = [
|
|
"cross_traffic_unittest.cc",
|
|
]
|
|
deps = [
|
|
":emulated_network",
|
|
"../:test_support",
|
|
"../../api:simulated_network_api",
|
|
"../../call:simulated_network",
|
|
"../../rtc_base:logging",
|
|
"../../rtc_base:rtc_event",
|
|
"//third_party/abseil-cpp/absl/memory",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("feedback_generator") {
|
|
testonly = true
|
|
sources = [
|
|
"feedback_generator.cc",
|
|
"feedback_generator.h",
|
|
]
|
|
deps = [
|
|
":emulated_network",
|
|
"../../api/transport:test_feedback_generator_interface",
|
|
"../../call:simulated_network",
|
|
"../../rtc_base:checks",
|
|
"../time_controller",
|
|
"//third_party/abseil-cpp/absl/memory",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("feedback_generator_unittest") {
|
|
testonly = true
|
|
sources = [
|
|
"feedback_generator_unittest.cc",
|
|
]
|
|
deps = [
|
|
"../:test_support",
|
|
"../../api/transport:test_feedback_generator",
|
|
]
|
|
}
|
|
|
|
rtc_source_set("network_emulation_unittests") {
|
|
testonly = true
|
|
deps = [
|
|
":cross_traffic_unittest",
|
|
":feedback_generator_unittest",
|
|
":network_emulation_pc_unittest",
|
|
":network_emulation_unittest",
|
|
]
|
|
}
|