1140f97e48
Reason for revert: Fixing the Gn error and try to reland. Original issue's description: > Revert of Creating webrtc/modules:module_api (patchset #5 id:80001 of https://codereview.webrtc.org/2838873002/ ) > > Reason for revert: > Causes build problem: https://build.chromium.org/p/client.webrtc/builders/iOS64%20Sim%20Debug%20%28iOS%209.0%29/builds/1630/steps/generate%20build%20files%20%28mb%29/logs/stdio > > Original issue's description: > > Creating webrtc/modules:module_api > > > > This target keeps track of .h the files under webrtc/modules/include/ > > that are not part of any target. > > If a .h file is not part of a target the 'gn check' utility is not > > able to spot if a target is missing a dependency because even if > > it parses '#include' directives it is not able to find a target that > > contains these headers. > > > > BUG=webrtc:7513 > > NOTRY=True > > > > Review-Url: https://codereview.webrtc.org/2838873002 > > Cr-Commit-Position: refs/heads/master@{#17880} > > Committed:5a1a092ed0> > TBR=kjellander@webrtc.org > # Skipping CQ checks because original CL landed less than 1 days ago. > NOPRESUBMIT=true > NOTREECHECKS=true > NOTRY=true > BUG=webrtc:7513 > > Review-Url: https://codereview.webrtc.org/2839963005 > Cr-Commit-Position: refs/heads/master@{#17881} > Committed:bb08c3e296TBR=kjellander@webrtc.org # Skipping CQ checks because original CL landed less than 1 days ago. NOPRESUBMIT=true NOTREECHECKS=true NOTRY=true TBR=kjellander@webrtc.org BUG=webrtc:7513 Review-Url: https://codereview.webrtc.org/2843913002 Cr-Commit-Position: refs/heads/master@{#17884}
105 lines
3.5 KiB
Plaintext
105 lines
3.5 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../webrtc.gni")
|
|
|
|
rtc_static_library("congestion_controller") {
|
|
sources = [
|
|
"congestion_controller.cc",
|
|
"delay_based_bwe.cc",
|
|
"delay_based_bwe.h",
|
|
"include/congestion_controller.h",
|
|
"include/receive_side_congestion_controller.h",
|
|
"include/send_side_congestion_controller.h",
|
|
"median_slope_estimator.cc",
|
|
"median_slope_estimator.h",
|
|
"probe_bitrate_estimator.cc",
|
|
"probe_bitrate_estimator.h",
|
|
"probe_controller.cc",
|
|
"probe_controller.h",
|
|
"receive_side_congestion_controller.cc",
|
|
"send_side_congestion_controller.cc",
|
|
"transport_feedback_adapter.cc",
|
|
"transport_feedback_adapter.h",
|
|
"trendline_estimator.cc",
|
|
"trendline_estimator.h",
|
|
]
|
|
|
|
if (rtc_enable_bwe_test_logging) {
|
|
defines = [ "BWE_TEST_LOGGING_COMPILE_TIME_ENABLE=1" ]
|
|
} else {
|
|
defines = [ "BWE_TEST_LOGGING_COMPILE_TIME_ENABLE=0" ]
|
|
}
|
|
|
|
# TODO(jschuh): Bug 1348: fix this warning.
|
|
configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
deps = [
|
|
"..:module_api",
|
|
"../..:webrtc_common",
|
|
"../../base:rtc_base",
|
|
"../../base:rtc_base_approved",
|
|
"../../base:rtc_numerics",
|
|
"../../logging:rtc_event_log_api",
|
|
"../../system_wrappers",
|
|
"../bitrate_controller",
|
|
"../pacing",
|
|
"../remote_bitrate_estimator",
|
|
"../rtp_rtcp",
|
|
"../utility",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("congestion_controller_unittests") {
|
|
testonly = true
|
|
|
|
# Skip restricting visibility on mobile platforms since the tests on those
|
|
# gets additional generated targets which would require many lines here to
|
|
# cover (which would be confusing to read and hard to maintain).
|
|
if (!is_android && !is_ios) {
|
|
visibility = [ "//webrtc/modules:modules_unittests" ]
|
|
}
|
|
sources = [
|
|
"congestion_controller_unittest.cc",
|
|
"congestion_controller_unittests_helper.cc",
|
|
"congestion_controller_unittests_helper.h",
|
|
"delay_based_bwe_unittest.cc",
|
|
"delay_based_bwe_unittest_helper.cc",
|
|
"delay_based_bwe_unittest_helper.h",
|
|
"median_slope_estimator_unittest.cc",
|
|
"probe_bitrate_estimator_unittest.cc",
|
|
"probe_controller_unittest.cc",
|
|
"transport_feedback_adapter_unittest.cc",
|
|
"trendline_estimator_unittest.cc",
|
|
]
|
|
deps = [
|
|
":congestion_controller",
|
|
"../../base:rtc_base_approved",
|
|
"../../system_wrappers:system_wrappers",
|
|
"../../test:field_trial",
|
|
"../../test:test_support",
|
|
"../bitrate_controller:bitrate_controller",
|
|
"../pacing:pacing",
|
|
"../remote_bitrate_estimator:mock_remote_bitrate_observer",
|
|
"../remote_bitrate_estimator:remote_bitrate_estimator",
|
|
"../rtp_rtcp:rtp_rtcp",
|
|
"//testing/gmock",
|
|
]
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
}
|