806e06d136
Bug: webrtc:7580 Change-Id: I6d901afa97262b6c6d9fe6c7366df465ec77bfb3 Reviewed-on: https://webrtc-review.googlesource.com/c/113944 Reviewed-by: Sami Kalliomäki <sakal@webrtc.org> Reviewed-by: Seth Hampson <shampson@webrtc.org> Reviewed-by: Anders Carlsson <andersc@webrtc.org> Reviewed-by: Steve Anton <steveanton@webrtc.org> Commit-Queue: Florent Castelli <orphis@webrtc.org> Cr-Commit-Position: refs/heads/master@{#25993}
80 lines
2.6 KiB
Plaintext
80 lines
2.6 KiB
Plaintext
/*
|
|
* Copyright 2016 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCRtpEncodingParameters+Private.h"
|
|
|
|
@implementation RTCRtpEncodingParameters
|
|
|
|
@synthesize codecPayloadType = _codecPayloadType;
|
|
@synthesize isActive = _isActive;
|
|
@synthesize maxBitrateBps = _maxBitrateBps;
|
|
@synthesize minBitrateBps = _minBitrateBps;
|
|
@synthesize maxFramerate = _maxFramerate;
|
|
@synthesize numTemporalLayers = _numTemporalLayers;
|
|
@synthesize ssrc = _ssrc;
|
|
|
|
- (instancetype)init {
|
|
return [super init];
|
|
}
|
|
|
|
- (instancetype)initWithNativeParameters:
|
|
(const webrtc::RtpEncodingParameters &)nativeParameters {
|
|
if (self = [self init]) {
|
|
if (nativeParameters.codec_payload_type) {
|
|
_codecPayloadType = [NSNumber numberWithInt:*nativeParameters.codec_payload_type];
|
|
}
|
|
_isActive = nativeParameters.active;
|
|
if (nativeParameters.max_bitrate_bps) {
|
|
_maxBitrateBps =
|
|
[NSNumber numberWithInt:*nativeParameters.max_bitrate_bps];
|
|
}
|
|
if (nativeParameters.min_bitrate_bps) {
|
|
_minBitrateBps =
|
|
[NSNumber numberWithInt:*nativeParameters.min_bitrate_bps];
|
|
}
|
|
if (nativeParameters.max_framerate) {
|
|
_maxFramerate = [NSNumber numberWithInt:*nativeParameters.max_framerate];
|
|
}
|
|
if (nativeParameters.num_temporal_layers) {
|
|
_numTemporalLayers = [NSNumber numberWithInt:*nativeParameters.num_temporal_layers];
|
|
}
|
|
if (nativeParameters.ssrc) {
|
|
_ssrc = [NSNumber numberWithUnsignedLong:*nativeParameters.ssrc];
|
|
}
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (webrtc::RtpEncodingParameters)nativeParameters {
|
|
webrtc::RtpEncodingParameters parameters;
|
|
if (_codecPayloadType != nil) {
|
|
parameters.codec_payload_type = absl::optional<int>(_codecPayloadType.intValue);
|
|
}
|
|
parameters.active = _isActive;
|
|
if (_maxBitrateBps != nil) {
|
|
parameters.max_bitrate_bps = absl::optional<int>(_maxBitrateBps.intValue);
|
|
}
|
|
if (_minBitrateBps != nil) {
|
|
parameters.min_bitrate_bps = absl::optional<int>(_minBitrateBps.intValue);
|
|
}
|
|
if (_maxFramerate != nil) {
|
|
parameters.max_framerate = absl::optional<int>(_maxFramerate.intValue);
|
|
}
|
|
if (_numTemporalLayers != nil) {
|
|
parameters.num_temporal_layers = absl::optional<int>(_numTemporalLayers.intValue);
|
|
}
|
|
if (_ssrc != nil) {
|
|
parameters.ssrc = absl::optional<uint32_t>(_ssrc.unsignedLongValue);
|
|
}
|
|
return parameters;
|
|
}
|
|
|
|
@end
|